Clear["Global`*"]
(* implement the Laplace solution for a cylinder which is fed a current through the top boundary via a circular patch contact, while the entire bottom of the cylinder is on ground *)

d=1/4;
b=1;
c=2;

Nmax=25;
αT=Table[N[BesselJZero[1,j]],{j,1,Nmax}]

A[j_]:=N[2/(Pi b d)/αT[[j]]^2 BesselJ[1,d αT[[j]]/b]/Cosh[αT[[j]]c]/BesselJ[0,αT[[j]]]^2]

A[1]

AT=Table[A[j],{j,1,Nmax}]
(* don't get fooled by the small expansion coefficients, convergence is slow for a step function represented by a Bessel expansion! *)

Φ[s_,z_]:=
Sum[AT[[k]]BesselJ[0,αT[[k]]s/b]Sinh[αT[[k]]z],{k,1,Nmax}]+z/N[Pi b^2]

Φ[0,c]

Ez[s_,z_]:=-D[Φ[s,z1],z1]/.z1->z

Es[s_,z_]:=-D[Φ[s1,z],s1]/.s1->s

Plot[{Ez[s,c],-HeavisideTheta[d-s]/(Pi d^2)},{s,0,1},ExclusionsStyle->{Dashed}]

(* the current - assuming σ=1 *)
2Pi Integrate[-s HeavisideTheta[d-s]/(Pi d^2),{s,0,b}]

2Pi Integrate[s Ez[s,c],{s,0,b}]

ContourPlot[Φ[s,z],{s,0,b},{z,0,c},ContourLabels->True]

StreamDensityPlot[{Es[s,z],Ez[s,z]},{s,0,b},{z,0.6c,0.95c},ColorFunction->"NeonColors",AspectRatio->Automatic]

VectorPlot[{Es[s,z],Ez[s,z]},{s,0,b},{z,0.5c,0.85c},AspectRatio->Automatic,VectorScale->Automatic]
(* to have an indication of current density strength: -nb: we didn't go to the top to avoid the big current density there *)

Plot[Φ[s,c],{s,0,b}]

(* note: the potential is not flat over the contact area! - we average it for Ohm's law *)

Rg=Integrate[s Φ[s,c],{s,0,d}]/(d^2/2)

(* this falls in-between two extreme values: patch area = full area -> lowest geometric resistance, and cylinder radius = patch radius, flow confined to s<d -> large geometric resistance *)

{c/N[Pi b^2],c/N[Pi d^2]}

(* the result is closer to the cylinder value fed through the entire cross section A=Pi b^2 than to the value for a radius=d cylinder. This shows that the cylinder volume contributes quite a bit towards the conduction. *)

(* note the implication about the potential plot: there is positive potential at the top of the cylinder outside the patch contact area, this leads to an electric field results in downward flow. *)