Lossy Dielectric: matching two regions

PHYS 4020 3.0

February 28, 2013

Explanation

We define a material through its constituent relation constants.
σ  is the conductivity
μ  is the permeability
ϵ  is the permittivity
We will find out by experimenting with the notebook that in the end the frequency of the wave 
ω = 2π f
plays an important role in determining the properties (resistive vs capacitive).

A dielectric with some conductivity is considered lossy, since a conduction current density will play a role that competes with the displacement current density; conduction in a medium leads to Joule heating, which implies a loss of power (which means that the electric and magnetic field amplitudes have to suffer from attenuation).
If the conductivity σ = 0, we have no losses, since there is no conduction, j = σ E vanishes.
In an ideal conductor σ = ∞, and presumably the capacitive properties disappear, i.e., the displacement current density becomes negligible.

The parameter that determines the ratio of conduction to displacement current is
tan(θ) = σ/(ωϵ)
which demonstrates the frequency dependence.

At large frequency conduction effects are suppressed.

In this notebook we consider two adjacent homogeneous regions: a wave approaches from the left, some of it is transmitted, and some is reflected. The regions are labeled as 1 and 2.

We define the basic parameters first:

Clear["Global`*"]
ω1=N[2Pi 10^6]; (* 1 MHz *)
ϵ0=8.854 10^(-12);
μ0=N[4Pi 10^(-7)];

Now we choose our example parameter values: a case where conduction and displacement compete.
For region 1 we make the losses small (mostly dielectric medium):

ω=10 ω1; (* 10 MHz *)
ϵ1=14ϵ0; (* relative permittivity = 14 *)
μ1=1.0 μ0; (* relative permeability = 1.1 *)
σ1=10^-4; (* conductivity in SI: *)
σ1/ω/ϵ1

For region 2 we choose a more conductive property:

ϵ2=1.0ϵ0; (* relative permittivity = 14 *)
μ2=1.1 μ0; (* relative permeability = 1.1 *)
σ2=10^-2; (* conductivity in SI: *)
σ2/ω/ϵ2

α1=ω Sqrt[μ1 ϵ1/2(Sqrt[1+(σ1/ω /ϵ1)^2]-1)]
β1=ω Sqrt[μ1 ϵ1/2(Sqrt[1+(σ1/ω/ ϵ1)^2]+1)]

α2=ω Sqrt[μ2 ϵ2/2(Sqrt[1+(σ2/ω /ϵ2)^2]-1)]
β2=ω Sqrt[μ2 ϵ2/2(Sqrt[1+(σ2/ω/ ϵ2)^2]+1)]
(* β = k is the wavenumber, while α gives the attenuation *)

Observe how α and β acquired almost the same value, since σ/ω/ϵ is large.

η1=Sqrt[I ω μ1/(σ1+I ω  ϵ1)]
(* complex impedance *)

η2=Sqrt[I ω μ2/(σ2+I ω  ϵ2)]

{Abs[η1],Abs[η2]}
(* controls the strength of the H field compared to E,
the imaginary part of η -> the phase by which H lags behind E *)

E0i=1; (* 1 Volt/meter *)
H0i=E0i/η1

In LossyDielectric2.PDF we derive the matching conditions, and the resulting reflection and transmission coefficients (which are complex amplitudes, since the impedances η1 and η2 are complex).

rf=(η2-η1)/(η1+η2)

tr=2η2/(η1+η2)

Efield1=ComplexExpand[Re[E0i (Exp[-α1 z]Exp[I(ω t-β1 z)]+rf Exp[α1 z]Exp[I(ω t+β1 z)])]]

Hfield1=ComplexExpand[Re[H0i( Exp[-α1 z]Exp[I(ω t-β1 z)]-rf Exp[α1 z]Exp[I(ω t+β1 z)])]]

T=2Pi/ω
λ1=2Pi/β1
λ2=2Pi/β2

In order to show the electric and magnetic field strength on the same graph we boost the magnetic strength by 75% of its attenuation factor.

PL1=Plot[{Efield1 /. t->T/2,0.75Abs[η1]Hfield1 /. t->T/4},{z,-2λ1,0},PlotRange->All,PlotStyle->{Blue,Green}]

Efield2=ComplexExpand[Re[E0i tr Exp[-α2 z]Exp[I(ω t-β2 z)]]]

Hfield2=ComplexExpand[Re[E0i tr/η2  Exp[-α2 z]Exp[I(ω t-β2 z)]]]

PL2=Plot[{Efield2 /. t->T/2,0.75Abs[η1]Hfield2 /. t->T/4},{z,0,λ2},PlotRange->All,PlotStyle->{Blue,Green}]

Show[{PL1,PL2},PlotRange->All]

To visualize the wave nature we animate the plot over time.

Animate[Show[Plot[Evaluate@{Efield1/. t->s,0.75Abs[η1]Hfield1/. t->s} ,{z,-2λ1,0},PlotRange->{{-2λ1,λ2},{-2E0i,2E0i}},PlotStyle->{Blue,Green}],Plot[Evaluate@{Efield2/. t->s,0.75Abs[η1]Hfield2/. t->s} ,{z,0,λ2},PlotRange->{{-2λ1,λ2},{-2E0i,2E0i}},PlotStyle->{Blue,Green}]],{s,0,2T},AnimationRunning->False]

In the limit that region 2 represents a perfect conductor the fields in region 1 are standing waves:
E1_x = 2E0i sin(β1 z) sin(ωt),    and
H1_y = (2E0i/η1) cos(β1 z) cos(ωt)  .

The standing waves are phase-shifted by 90 degrees, and the temporal oscillations are also out of phase by the same amount.
Note how the magnetic field has antinodes at the metal surface.

Inside the lossy region the phase delay of H with respect to E is maximally 45 degrees.